Auto Oper ircop

Voir le sujet précédent Voir le sujet suivant Aller en bas

Auto Oper ircop

Message par Admin le Mar 19 Jan - 10:58

menu status,channel,menubar {
 Auto Oper : ao
}

alias ao {
 if (!$dialog(Auto-Oper)) {
   dialog -m Auto-Oper Auto-Oper
   DialogStart
 }
}

dialog -l Auto-Oper {
 title "Auto Oper"
 size -1 -1 209 124
 option dbu
 box "Netzwerkliste", 1, 3 1 73 120
 list 2, 6 10 67 109, hsbar vsbar size
 box "Hinzufügen/Bearbeiten", 3, 79 1 127 104
 text "Netzwerk:", 4, 84 25 26 8
 combo 5, 111 24 90 9, edit drop
 text "Name:", 6, 84 42 16 8
 edit "", 7, 111 41 90 10, autohs
 text "Passwort:", 8, 84 59 25 8
 edit "", 9, 111 58 90 10, pass autohs
 button "Speichern", 10, 84 74 55 12
 button "O.k", 11, 79 108 127 12, cancel
 button "Löschen", 12, 84 88 118 12
 check "Auto Oper Aktivieren", 13, 84 11 116 8
 button "Nix Speichern", 14, 146 74 55 12
}

on *:dialog:Auto-Oper:*:*: {
 if ($devent == edit) {
   if ($did == 7) {
     if (($did($dname, 7).text) && ($did($dname, 9).text) && ($did($dname, 5).text != $null)) {
       did -e $dname 10
     }
     else {
       did -b $dname 10
     }
     if ($did($dname, 5).enabled == $false) {
       if ($readini(AutoOper.ini, $did($dname, 5).text, Name) == $did($dname, 7).text) {
         did -b $dname 10
       }
       else {
         did -e $dname 10
       }
     }
   }
   if ($did == 9) {
     if (($did($dname, 7).text) && ($did($dname, 9).text) && ($did($dname, 5).text != $null)) {
       did -e $dname 10
     }
     else {
       did -b $dname 10
     }
     if ($did($dname, 5).enabled == $false) {
       if ($readini(AutoOper.ini, $did($dname, 5).text, Passwort) == $did($dname, 9).text) {
         did -b $dname 10
       }
       else {
         did -e $dname 10
       }
     }
   }
 }
 if ($devent == sclick) {
   if ($did == 13) {
     if ($did($dname, 5).enabled == $false) {
       if ($readini(AutoOper.ini, $did($dname, 5).text, On) != $did($dname, 13).state) {
         did -e $dname 10
       }
       else {
         if (($readini(AutoOper.ini, $did($dname, 5).text, Passwort) == $did($dname, 9).text) && ($readini(AutoOper.ini, $did($dname, 5).text, Name) == $did($dname, 7).text)) {
           did -b $dname 10
         }
       }
     }
   }
   if ($did == 5) {
     var %a = $ini(AutoOper.ini, 0)
     while (%a) {
       if ($did($dname, 5).text == $ini(AutoOper.ini, %a)) {
         did -e $dname 12,14
         did -b $dname 5,10
         did -ra $dname 5 $did($dname, 5).text
         did -c $dname 5 1
         did -ra $dname 7 $readini(AutoOper.ini, $did($dname, 5).text, Name)
         did -ra $dname 9 $readini(AutoOper.ini, $did($dname, 5).text, Passwort)
         if ($readini(AutoOper.ini, $did($dname, 5).text, On) == 1) {
           did -c $dname 13
         }
       }
       dec %a
     }
   }
   if ($did == 10) {
     writeini AutoOper.ini $did($dname, 5).text Name $did($dname, 7).text
     writeini AutoOper.ini $did($dname, 5).text Passwort $did($dname, 9).text
     writeini AutoOper.ini $did($dname, 5).text On $did($dname, 13).state
     did -r $dname 7,9
     did -u $dname 13
     did -b $dname 10,12,14
     ListNetwork
     if (!$did($dname, 5).enabled) {
       did -re $dname 5
       ComboNetzwerk
     }
   }
   if ($did == 14) {
     did -r $dname 7,9
     did -u $dname 13
     did -b $dname 10,12,14
     if (!$did($dname, 5).enabled) {
       did -re $dname 5
       ComboNetzwerk
     }
   }
   if ($did == 12) {
     var %input = $input(Bist du dir sicher?, qvy, Löschen?)
     if (%input == $yes) {
       remini AutoOper.ini $did($dname, 5).text
       ListNetwork
       did -b $dname 12,14
       did -r $dname 7,9
       did -u $dname 13
       if (!$did($dname, 5).enabled) {
         did -re $dname 5
         ComboNetzwerk
       }
     }
   }
   if ($did == 2) {
     if ($did($dname, 2).seltext) {
       did -e $dname 12,14
       did -b $dname 5,10
       did -ra $dname 5 $did($dname, 2).seltext
       did -c $dname 5 1
       did -ra $dname 7 $readini(AutoOper.ini, $did($dname, 5).text, Name)
       did -ra $dname 9 $readini(AutoOper.ini, $did($dname, 5).text, Passwort)
       if ($readini(AutoOper.ini, $did($dname, 5).text, On) == 1) {
         did -c $dname 13
       }
     }
   }
 }
}

on *:CONNECT:{
 var %a = $ini(AutoOper.ini, 0)
 while (%a) {
   if ($network == $ini(AutoOper.ini, %a)) {
     if ($readini(AutoOper.ini, $ini(AutoOper.ini, %a), On) == 1) {
       .oper $readini(AutoOper.ini, $ini(AutoOper.ini, %a), Name) $readini(AutoOper.ini, $ini(AutoOper.ini, %a), Passwort)
     }
   }
   dec %a
 }
}

alias -l ListNetwork {
 var %dname = Auto-Oper
 did -r %dname 2
 var %a = $ini(AutoOper.ini, 0)
 while (%a) {
   did -az %dname 2 $ini(AutoOper.ini, %a)
   dec %a
 }
}

alias -l DialogStart {
 var %dname = Auto-Oper
 did -b %dname 10,12,14
 ComboNetzwerk
 ListNetwork
}

alias -l ComboNetzwerk {
 var %dname = Auto-Oper
 var %a = $scon(0)
 while (%a) {
   did -a %dname 5 $scon(%a).network
   dec %a
 }
}

Admin
Admin

Messages : 34
Date d'inscription : 15/10/2015

http://remotes-irc-addons.forum-officiel.com

Revenir en haut Aller en bas

Voir le sujet précédent Voir le sujet suivant Revenir en haut

- Sujets similaires

 
Permission de ce forum:
Vous ne pouvez pas répondre aux sujets dans ce forum